home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib15.dsk / CATDATE (NO CLOCK CARD).bas < prev    next >
BASIC Source File  |  2023-02-26  |  2KB  |  68 lines
  1. 10  REM  **********************
  2. 11  REM  * CATALOG DATE HELLO *
  3. 12  REM  * BY ARTHUR L. MENA  *
  4. 13  REM  * COPYRIGHT (C) 1983 *
  5. 14  REM  * BY MICROSPARC, INC *
  6. 15  REM  * LINCOLN, MA. 01773 *
  7. 16  REM  **********************
  8. 120  REM 
  9. 130  REM 
  10. 140  REM  This version of the program
  11. 150  REM  is for those who do not have
  12. 160  REM  a clock/calendar card in
  13. 170  REM  their Apple
  14. 180  REM 
  15. 220  REM 
  16. 230  REM  Poke CATDATE into memory
  17. 240  REM 
  18. 250 B$ =  CHR$(7) + CHR$(7) + CHR$(7): REM  3 Bells
  19. 260  RESTORE 
  20. 270  FOR I = 44686 TO 44732
  21. 280  READ D: POKE I,D
  22. 290  NEXT I
  23. 300  REM 
  24. 310  REM  Poke JSR CATDATE into memory
  25. 320  REM 
  26. 330  POKE 45611,32: POKE 45612,143: POKE 15613,174
  27. 340  POKE 45574,32: POKE 45575,143: POKE 45576,174
  28. 350  REM 
  29. 360  REM  Change file name length to 21
  30. 370  REM 
  31. 380  POKE 45608,21: POKE 45571,21
  32. 390  REM 
  33. 400  REM 
  34. 410  DATA  0,173,95,170,201,4,240,12,201,48,240,8,201,26,240,4,201,0,208,23,174,156,179,189,200,180,48,15,160,8,185,223,188,157,222,180,232,136,16,246
  35. 420  DATA  32,55,176,174,156,179,96
  36. 430  REM 
  37. 440  REM 
  38. 450  REM  Input date from keyboard
  39. 460  REM 
  40. 470  TEXT : HOME 
  41. 480  VTAB 5: HTAB 10: PRINT "CATDATE INSTALLED": PRINT 
  42. 490  PRINT " INPUT THE CURRENT DATE": PRINT 
  43. 500  PRINT 
  44. 510  REM 
  45. 520  VTAB 10: INPUT " WHAT IS THE CURRENT MONTH (1-12) ?";MN$
  46. 530  IF  VAL(MN$) <1  OR  VAL(MN$) >12  THEN  PRINT B$;"MONTH INCORRECT": GOTO 520
  47. 540  VTAB 12: INPUT " WHAT IS THE CURRENT DAY   (1-31) ?";DA$
  48. 550  IF  VAL(DA$) <1  OR  VAL(DA$) >32  THEN  PRINT B$;"DAY INCORRECT": GOTO 540
  49. 560 YR$ = "/82"
  50. 570  REM 
  51. 580 DA$ =  STR$( VAL(DA$))
  52. 590  IF  VAL(DA$) <10  THEN DA$ = "0" +DA$
  53. 600 MN$ =  STR$( VAL(MN$))
  54. 610  IF  VAL(MN$) <10  THEN MN$ = "0" +MN$
  55. 620  REM 
  56. 630 DT = 48351: REM  $BCDF
  57. 640 DT$ = MN$ +"/" +DA$ +YR$ +" "
  58. 650  PRINT : PRINT 
  59. 660  PRINT DT$" HAS BEEN INSTALLED AS THE     CURRENT DATE"
  60. 670  REM 
  61. 680  REM  Poke date into memory
  62. 690  REM 
  63. 700 J = 8
  64. 710  FOR I = 0 TO  LEN(DT$) -1
  65. 720  POKE DT +J, ASC( MID$ (DT$,I +1,1)) +128
  66. 730 J = J -1
  67. 740  NEXT I
  68. 750  END